Module

Provides functions to deal with modules during compilation time.

It allows a developer to dynamically add, delete and register attributes, attach documentation and so forth.

After a module is compiled, using many of the functions in this module will raise errors, since it is out of their scope to inspect runtime data. Most of the runtime data can be inspected via the __info__(attr) function attached to each compiled module.

Module attributes

Each module can be decorated with one or more attributes. The following ones are currently defined by Elixir:

@after_compile

A hook that will be invoked right after the current module is compiled. Accepts a module or a tuple {<module>, <function atom>}. See the “Compile callbacks” section below.
@before_compile

A hook that will be invoked before the module is compiled. Accepts a module or a tuple {<module>, <function/macro atom>}. See the “Compile callbacks” section below.
@behaviour (notice the British spelling)

Behaviours can be referenced by modules to ensure they implement required specific function signatures defined by @callback.

For example, you can specify the URI.Parser behaviour as follows:
```
defmodule URI.Parser do
  @doc "Parses the given URL"
  @callback parse(uri_info :: URI.t) :: URI.t

  @doc "Defines a default port"
  @callback default_port() :: integer
end

And then a module may use it as:

defmodule URI.HTTP do
  @behaviour URI.Parser
  def default_port(), do: 80
  def parse(info), do: info
end
```
If the behaviour changes or URI.HTTP does not implement one of the callbacks, a warning will be raised.

Specifies an OTP or user-defined behaviour.

Example
```
defmodule M do
  @behaviour :gen_event

  # ...
end
```
@callback, @macrocallback, and @optional_callbacks

These attributes are used to define a behaviour (as shown in the documentation for @behaviour above). @callback defines a function callback, @macrocallback defines a macro callback, and @optional_callbacks specifies which callbacks and macrocallbacks are optional.
@compile

Defines options for module compilation. This is used to configure both Elixir and Erlang compilers, as any other compilation pass added by external tools.

Multiple uses of @compile will accumulate instead of overriding previous ones. See the “Compile options” section below.

Example
```
defmodule M do
  @compile {:inline, myfun: 1}

  def myfun(arg) do
    to_string(arg)
  end
end
```
@doc

Provides documentation for the function or macro that follows the attribute.

Accepts a string (often a heredoc) or false where @doc false will make the function/macro invisible to the documentation extraction tools like ExDoc.

Can be invoked more than once.

Example
```
defmodule M do
  @doc "Hello world"
  def hello do
    "world"
  end

  @doc """
  Sums `a` to `b`.
  """
  def sum(a, b) do
    a + b
  end
end
```
@dialyzer

Defines warnings to request or suppress when using a version of :dialyzer that supports module attributes.

Accepts an atom, a tuple, or a list of atoms and tuples.

For the list of supported warnings, see :dialyzer module.

Multiple uses of @dialyzer will accumulate instead of overriding previous ones.

Example
```
defmodule M do
  @dialyzer {:nowarn_function, myfun: 1}

  def myfun(arg) do
    M.not_a_function(arg)
  end
end
```
@external_resource

Specifies an external resource to the current module.

Many times a module embeds information from an external file. This attribute allows the module to annotate which external resources have been used.

Tools like Mix may use this information to ensure the module is recompiled in case any of the external resources change.
@file

Changes the filename used in stacktraces for the function or macro that follows the attribute.

Accepts a string. Can be used more than once.

Example
```
defmodule M do
  @doc "Hello world"
  @file "hello.ex"
  def hello do
    "world"
  end
end
```
@moduledoc

Provides documentation for the current module.

Accepts a string (which is often a heredoc) or false where @moduledoc false will make the module invisible to the documentation extraction tools like ExDoc.

Example
```
defmodule M do
  @moduledoc """
  A very useful module
  """
end
```
@on_definition

A hook that will be invoked when each function or macro in the current module is defined. Useful when annotating functions.

Accepts a module or a tuple {<module>, <function atom>}. See the “Compile callbacks” section below.
@on_load

A hook that will be invoked whenever the module is loaded.

Accepts a function atom of a function in the current module. The function must have arity 0 (no arguments) and has to return :ok, otherwise the loading of the module will be aborted.

Example
```
defmodule M do
  @on_load :load_check

  def load_check do
    if some_condition() do
      :ok
    else
      nil
    end
  end

  def some_condition do
    false
  end
end
```
@vsn

Specify the module version. Accepts any valid Elixir value.

Example
```
defmodule M do
  @vsn "1.0"
end
```

The following attributes are part of typespecs and are also reserved by Elixir:

@type - defines a type to be used in @spec
@typep - defines a private type to be used in @spec
@opaque - defines an opaque type to be used in @spec
@spec - provides a specification for a function
@callback - provides a specification for a behaviour callback
@macrocallback - provides a specification for a macro behaviour callback
@optional_callbacks - specifies which behaviour callbacks and macro behaviour callbacks are optional

In addition to the built-in attributes outlined above, custom attributes may also be added. A custom attribute is any valid identifier prefixed with an @ and followed by a valid Elixir value:

defmodule M do
  @custom_attr [some: "stuff"]
end

For more advanced options available when defining custom attributes, see register_attribute/3.

Compile callbacks

There are three callbacks that are invoked when functions are defined, as well as before and immediately after the module bytecode is generated.

`@after_compile`

A hook that will be invoked right after the current module is compiled.

Accepts a module or a tuple {<module>, <function atom>}. The function must take two arguments: the module environment and its bytecode. When just a module is provided, the function is assumed to be __after_compile__/2.

Example

defmodule M do
  @after_compile __MODULE__

  def __after_compile__(env, _bytecode) do
    IO.inspect env
  end
end

`@before_compile`

A hook that will be invoked before the module is compiled.

Accepts a module or a tuple {<module>, <function/macro atom>}. The function/macro must take one argument: the module environment. If it’s a macro, its returned value will be injected at the end of the module definition before the compilation starts.

When just a module is provided, the function/macro is assumed to be __before_compile__/1.

Note: unlike @after_compile, the callback function/macro must be placed in a separate module (because when the callback is invoked, the current module does not yet exist).

Example

defmodule A do
  defmacro __before_compile__(_env) do
    quote do
      def hello, do: "world"
    end
  end
end

defmodule B do
  @before_compile A
end

`@on_definition`

A hook that will be invoked when each function or macro in the current module is defined. Useful when annotating functions.

Accepts a module or a tuple {<module>, <function atom>}. The function must take 6 arguments:

the module environment
kind: :def, :defp, :defmacro, or :defmacrop
function/macro name
list of quoted arguments
list of quoted guards
quoted function body

Note the hook receives the quoted arguments and it is invoked before the function is stored in the module. So Module.defines?/2 will return false for the first clause of every function.

If the function/macro being defined has multiple clauses, the hook will be called for each clause.

Unlike other hooks, @on_definition will only invoke functions and never macros. This is because the hook is invoked inside the context of the function (and nested function definitions are not allowed in Elixir).

When just a module is provided, the function is assumed to be __on_definition__/6.

Example

defmodule H do
  def on_def(_env, kind, name, args, guards, body) do
    IO.puts "Defining #{kind} named #{name} with args:"
    IO.inspect args
    IO.puts "and guards"
    IO.inspect guards
    IO.puts "and body"
    IO.puts Macro.to_string(body)
  end
end

defmodule M do
  @on_definition {H, :on_def}

  def hello(arg) when is_binary(arg) or is_list(arg) do
    "Hello" <> to_string(arg)
  end

  def hello(_) do
    :ok
  end
end

Compile options

The @compile attribute accepts diverse options that is used by both Elixir and Erlang compilers. Some of the common use cases are documented below:

@compile :debug_info - includes :debug_info regardless of the setting in Code.compiler_options
@compile {:debug_info, false} - disables :debug_info regardless of the setting in Code.compiler_options
@compile {:inline, some_fun: 2, other_fun: 3} - inlines the given name/arity pairs
@compile {:autoload, false} - disables automatic loading of modules after compilation. Instead, the module will be loaded after it is dispatched to

You can see a handful more options used by the Erlang compiler in the documentation for the :compile module.

Summary

Functions

__info__(kind): Provides runtime information about functions and macros defined by the module, enables docstring extraction, etc
add_doc(module, line, kind, tuple, signature \\ [], doc): Attaches documentation to a given function or type
concat(list): Concatenates a list of aliases and returns a new alias
concat(left, right): Concatenates two aliases and returns a new alias
create(module, quoted, opts): Creates a module with the given name and defined by the given quoted expressions
defines?(module, tuple): Checks if the module defines the given function or macro
defines?(module, tuple, kind): Checks if the module defines a function or macro of the given kind
definitions_in(module): Returns all functions defined in module
definitions_in(module, kind): Returns all functions defined in module, according to its kind
delete_attribute(module, key): Deletes all attributes that match the given key
eval_quoted(module, quoted, binding \\ [], opts \\ []): Evaluates the quoted contents in the given module’s context
get_attribute(module, key): Gets the given attribute from a module
make_overridable(module, tuples): Makes the given functions in module overridable
open?(module): Checks if a module is open, i.e. it is currently being defined and its attributes and functions can be modified
overridable?(module, tuple): Returns true if tuple in module is marked as overridable
put_attribute(module, key, value): Puts an Erlang attribute to the given module with the given key and value
register_attribute(module, new, opts): Registers an attribute. By registering an attribute, a developer is able to customize how Elixir will store and accumulate the attribute values
safe_concat(list): Concatenates a list of aliases and returns a new alias only if the alias was already referenced
safe_concat(left, right): Concatenates two aliases and returns a new alias only if the alias was already referenced
split(module): Splits the given module name into binary parts

Functions

info(kind)

__info__(:attributes | :compile | :exports | :functions | :macros | :md5 | :module | :native_addresses) ::
  atom |
  [{atom, any} | {atom, byte, integer}]

Provides runtime information about functions and macros defined by the module, enables docstring extraction, etc.

Each module gets an __info__/1 function when it’s compiled. The function takes one of the following atoms:

:functions - keyword list of public functions along with their arities
:macros - keyword list of public macros along with their arities
:module - module name (Module == Module.__info__(:module))

In addition to the above, you may also pass to __info__/1 any atom supported by :erlang.module_info/0 which also gets defined for each compiled module.

For a list of supported attributes and more information, see Modules – Erlang Reference Manual.

add_doc(module, line, kind, tuple, signature \\ [], doc)

Attaches documentation to a given function or type.

It expects the module the function/type belongs to, the line (a non negative integer), the kind (def or defmacro), a tuple representing the function and its arity, the function signature (the signature should be omitted for types) and the documentation, which should be either a binary or a boolean.

Examples

defmodule MyModule do
  Module.add_doc(__MODULE__, __ENV__.line + 1, :def, {:version, 0}, [], "Manually added docs")
  def version, do: 1
end

concat(list)

concat([binary | atom]) :: atom

Concatenates a list of aliases and returns a new alias.

Examples

iex> Module.concat([Foo, Bar])
Foo.Bar

iex> Module.concat([Foo, "Bar"])
Foo.Bar

concat(left, right)

concat(binary | atom, binary | atom) :: atom

Concatenates two aliases and returns a new alias.

Examples

iex> Module.concat(Foo, Bar)
Foo.Bar

iex> Module.concat(Foo, "Bar")
Foo.Bar

create(module, quoted, opts)

Creates a module with the given name and defined by the given quoted expressions.

The line where the module is defined and its file must be passed as options.

Examples

contents =
  quote do
    def world, do: true
  end

Module.create(Hello, contents, Macro.Env.location(__ENV__))

Hello.world #=> true

Differences from `defmodule`

Module.create/3 works similarly to defmodule and return the same results. While one could also use defmodule to define modules dynamically, this function is preferred when the module body is given by a quoted expression.

Another important distinction is that Module.create/3 allows you to control the environment variables used when defining the module, while defmodule automatically shares the same environment.

defines?(module, tuple)

Checks if the module defines the given function or macro.

Use defines?/3 to assert for a specific type.

Examples

defmodule Example do
  Module.defines? __MODULE__, {:version, 0} #=> false
  def version, do: 1
  Module.defines? __MODULE__, {:version, 0} #=> true
end

defines?(module, tuple, kind)

Checks if the module defines a function or macro of the given kind.

kind can be any of :def, :defp, :defmacro or :defmacrop.

Examples

defmodule Example do
  Module.defines? __MODULE__, {:version, 0}, :defp #=> false
  def version, do: 1
  Module.defines? __MODULE__, {:version, 0}, :defp #=> false
end

definitions_in(module)

Returns all functions defined in module.

Examples

defmodule Example do
  def version, do: 1
  Module.definitions_in __MODULE__ #=> [{:version, 0}]
end

definitions_in(module, kind)

Returns all functions defined in module, according to its kind.

Examples

defmodule Example do
  def version, do: 1
  Module.definitions_in __MODULE__, :def  #=> [{:version, 0}]
  Module.definitions_in __MODULE__, :defp #=> []
end

delete_attribute(module, key)

delete_attribute(atom, atom) :: :ok

Deletes all attributes that match the given key.

Examples

defmodule MyModule do
  Module.put_attribute __MODULE__, :custom_threshold_for_lib, 10
  Module.delete_attribute __MODULE__, :custom_threshold_for_lib
end

eval_quoted(module, quoted, binding \\ [], opts \\ [])

Evaluates the quoted contents in the given module’s context.

A list of environment options can also be given as argument. See Code.eval_string/3 for more information.

Raises an error if the module was already compiled.

Examples

defmodule Foo do
  contents = quote do: (def sum(a, b), do: a + b)
  Module.eval_quoted __MODULE__, contents
end

Foo.sum(1, 2) #=> 3

For convenience, you can pass __ENV__ as an argument and all options will be automatically extracted from the environment:

defmodule Foo do
  contents = quote do: (def sum(a, b), do: a + b)
  Module.eval_quoted __MODULE__, contents, [], __ENV__
end

Foo.sum(1, 2) #=> 3

get_attribute(module, key)

get_attribute(atom, atom) :: term

Gets the given attribute from a module.

If the attribute was marked with accumulate with Module.register_attribute/3, a list is always returned. nil is returned if the attribute has not been marked with accumulate and has not been set to any value.

The @ macro compiles to a call to this function. For example, the following code:

@foo

Expands close to:

Module.get_attribute(__MODULE__, :foo)

Examples

defmodule Foo do
  Module.put_attribute __MODULE__, :value, 1
  Module.get_attribute __MODULE__, :value #=> 1

  Module.register_attribute __MODULE__, :value, accumulate: true
  Module.put_attribute __MODULE__, :value, 1
  Module.get_attribute __MODULE__, :value #=> [1]
end

make_overridable(module, tuples)

Makes the given functions in module overridable.

An overridable function is lazily defined, allowing a developer to customize it. See Kernel.defoverridable/1 for more information and documentation.

open?(module)

Checks if a module is open, i.e. it is currently being defined and its attributes and functions can be modified.

overridable?(module, tuple)

Returns true if tuple in module is marked as overridable.

put_attribute(module, key, value)

Puts an Erlang attribute to the given module with the given key and value.

The semantics of putting the attribute depends if the attribute was registered or not via register_attribute/3.

Examples

defmodule MyModule do
  Module.put_attribute __MODULE__, :custom_threshold_for_lib, 10
end

register_attribute(module, new, opts)

Registers an attribute. By registering an attribute, a developer is able to customize how Elixir will store and accumulate the attribute values.

Options

When registering an attribute, two options can be given:

:accumulate - several calls to the same attribute will accumulate instead of override the previous one. New attributes are always added to the top of the accumulated list.
:persist - the attribute will be persisted in the Erlang Abstract Format. Useful when interfacing with Erlang libraries.

By default, both options are false.

Examples

defmodule MyModule do
  Module.register_attribute __MODULE__,
    :custom_threshold_for_lib,
    accumulate: true, persist: false

  @custom_threshold_for_lib 10
  @custom_threshold_for_lib 20
  @custom_threshold_for_lib #=> [20, 10]
end

safe_concat(list)

safe_concat([binary | atom]) :: atom | no_return

Concatenates a list of aliases and returns a new alias only if the alias was already referenced.

If the alias was not referenced yet, fails with ArgumentError. It handles charlists, binaries and atoms.

Examples

iex> Module.safe_concat([Module, Unknown])
** (ArgumentError) argument error

iex> Module.safe_concat([List, Chars])
List.Chars

safe_concat(left, right)

safe_concat(binary | atom, binary | atom) ::
  atom |
  no_return

Concatenates two aliases and returns a new alias only if the alias was already referenced.

If the alias was not referenced yet, fails with ArgumentError. It handles charlists, binaries and atoms.

Examples

iex> Module.safe_concat(Module, Unknown)
** (ArgumentError) argument error

iex> Module.safe_concat(List, Chars)
List.Chars

split(module)

Splits the given module name into binary parts.

Examples

iex> Module.split Very.Long.Module.Name.And.Even.Longer
["Very", "Long", "Module", "Name", "And", "Even", "Longer"]

Module

Module attributes

Example

Example

Example

Example

Example

Example

Example

Example

Compile callbacks

@after_compile

Example

@before_compile

Example

@on_definition

Example

Compile options

Summary

Functions

Functions

__info__(kind)

add_doc(module, line, kind, tuple, signature \\ [], doc)

Examples

concat(list)

Examples

concat(left, right)

Examples

create(module, quoted, opts)

Examples

Differences from defmodule

defines?(module, tuple)

Examples

defines?(module, tuple, kind)

Examples

definitions_in(module)

Examples

definitions_in(module, kind)

Examples

delete_attribute(module, key)

Examples

eval_quoted(module, quoted, binding \\ [], opts \\ [])

Examples

get_attribute(module, key)

Examples

make_overridable(module, tuples)

open?(module)

overridable?(module, tuple)

put_attribute(module, key, value)

Examples

register_attribute(module, new, opts)

Options

Examples

safe_concat(list)

Examples

safe_concat(left, right)

Examples

split(module)

Examples

`@after_compile`

`@before_compile`

`@on_definition`

info(kind)

Differences from `defmodule`